　PIC電子工作ブログ: 3Dプリンタ

ラベル 3Dプリンタ の投稿を表示しています。すべての投稿を表示

2025年8月10日日曜日

LINE Messaging APIで3Dプリント終了通知

天気予報通り朝から雨模様。少し涼しくなりました。昨日の作業疲れと腰痛で午前中は横になってボーっと過ごしてしまいました。

午後から気力を振り絞り 3Dプリント終了通知ガジェットのLINE Notify から LINE Messaging APIへの移行作業です。写真の左に写っているフォトインタラプタが3Dプリンタの印刷完了時にヒートベッドが初期位置に戻ったときに遮られてメッセージを通知します。

以下はテストなので、監視開始とプリント完了の時間間隔が短いです。トラブルもなく無事に動いてよかったです。

ハードなどの詳細は下記の記事参照。当初は終了の検出にフォトリフレクタを使っていましたが、窓の近くで使うと誤動作したのでフォトインタラプタに変更しました。

3Dプリント印刷完了を通知する仕掛けの改修 2022年3月27日
LINEダッシュボタン、3Dプリンタ印刷完了を通知する機能の完成 2022年2月12日
LINEダッシュボタン、Windows版暗号化プログラム他 2022年2月11日

今回、ハードウェアの変更はなくプログラムを書き換えただけ。中身はESP32とMicroSDスロット、基板の裏面に3端子レギュレータが載っています。

LINE Messaging APIの使い方は以下のサイトを参考にさせて頂きました。

LINE Messaging API を使って ESP32 や M5Stack から簡単にメッセージを送信してみよう

ESP32に書き込むプログラムのスケッチは以下の通りです。無保証です。

//---------------------------------------------------------------
//                                                2025.08.10 naka
//                                                2022.02.02 naka
// LINE Dash Button(3Dプリント終了通知用)
// (LINE Messaging API版 2025.08.10)
//
// ・WiFi ssid,password,LINE channel ID, LINE channel passwordは、
//   暗号化してmicroSDに格納。送るメッセージは平文のまま記載。
//  ファイル名：setup.txt
//     暗号化したWiFi ssid, ssid-password, LINE channel ID,
//     LINE channel passwordをそれぞれ１行ずつ順に記載し、
//     5行目に起動時に送るメッセージ、
//     6行目に印刷完了時に送るメッセージを記載。
//  （例）
//    &D/)%X/C04S
//    *%/O-J_F$##5)CK`(%
//    #T('KLCS(76+$&E
//    $7L:#D?*$#8(#(:.$C7(9C'$)45J9C,5$CS&7(84$C7
//    3Dプリンタ監視開始
//    3Dプリント完了！
//---------------------------------------------------------------
#include <WiFi.h>
#include <HTTPClient.h>  
#include <SD.h>

#define SD_CS 16 // SD card chip select
#define SW    GPIO_NUM_13  // フォトインタラプタ（3D印刷完了検知）
#define LED_G 25
#define LED_R 27

#define ON  1
#define OFF 0

#define FILENAME "/setup.txt"

// LINE messaging API
const String token_url = "https://api.line.me/oauth2/v3/token";
const String msg_url   = "https://api.line.me/v2/bot/message/broadcast";

char ssid[64],password[64],channel_id[64],channel_pw[64],message1[128],message2[128];
int sw_newest;

// ssid,pw,channel id,channel pwを暗号化したときのキー
char* crypt_key = "Open Sesame";

void setup()
{
  pinMode(SW,INPUT_PULLUP);
  pinMode(LED_G,OUTPUT);
  pinMode(LED_R,OUTPUT);
  led_green(OFF);
  led_red(OFF);
  sw_newest = digitalRead(SW);
  if (read_setup_file(FILENAME)) {
    blink_red(10);
    esp_sleep_enable_ext0_wakeup(SW, LOW);
    esp_deep_sleep_start();
  }

  // GPIO割り込みピン設定
  gpio_wakeup_enable(SW, GPIO_INTR_LOW_LEVEL);
  // 動作確認のために動作開始メッセージを送る
  wifi_connect();          // WiFi接続
  send_msg2line(message1); // LINE notifyに1行目のメッセージ(監視開始)を送る
  wifi_disconnect();       // WiFi接続解除
  led_green(ON);

  // GPIO割り込みでのsleep復帰を有効化
  esp_sleep_enable_gpio_wakeup();
}

void loop(){
  // スリープ開始（復帰はこの後ろ）
  esp_light_sleep_start();
  
  wifi_connect();          // WiFi接続
  send_msg2line(message2); // LINE notifyに２行目のメッセージ(印刷終了)を送る
  wifi_disconnect();       // WiFi接続解除
  led_green(ON);
  while(!digitalRead(SW));
  delay(100);              // チャタリング対策
}

int sw_FallingEdge() {
  int prev = sw_newest;
  sw_newest = digitalRead(SW);
  return prev & ~sw_newest;  // change 1 -> 0
}

void led_green(int onoff) {
  if (onoff==ON) digitalWrite(LED_G,LOW);
  else           digitalWrite(LED_G,HIGH);
}

void led_red(int onoff) {
  if (onoff==ON) digitalWrite(LED_R,LOW);
  else           digitalWrite(LED_R,HIGH);
}

void wifi_connect() {
    WiFi.begin(ssid, password);
    int onoff = 0;
    while (WiFi.status() != WL_CONNECTED) {
        delay(500);
        if (onoff==0) led_green(ON);
        else          led_green(OFF);
        onoff ^= 1;
    }

    // 以下5行は、普通は不要なハズ
    IPAddress gateway(192,168,0,1);
    IPAddress subnet(255,255,255,0);
    IPAddress dns1(8, 8, 8, 8); // Google DNS primery server
    IPAddress dns2(8, 8, 4, 4); // Google DNS secondary server
    WiFi.config(WiFi.localIP(),gateway,subnet,dns1,dns2);    

    led_green(ON);
}

void wifi_disconnect() {
    WiFi.disconnect(true);
    led_green(OFF);
}

String get_token() {
    HTTPClient http;

    http.begin(token_url);
    http.addHeader("Content-Type","application/x-www-form-urlencoded");

    String  body = "grant_type=client_credentials&";
            body += "client_id=" + String(channel_id) + "&";
            body += "client_secret=" + String(channel_pw);
    int httpCode = http.POST(body);
    String token="";
    if(httpCode == 200){
        String S = http.getString();
        int i = S.indexOf("\"access_token\"");
        if((i>0) && (S.substring(i+15, i+16).equals("\""))){
            token = S.substring(i+16, i+16+174);
        }
    }
    else{ 
          blink_red(10);
          led_red(OFF);
    }
    http.end();
    return token;
}

void send_msg2line(String message) {  
    led_red(ON);

    String token = get_token();
    if (token.length()!=174) { // エラーなので赤色LED 5回点滅
      blink_red(5);
      led_red(ON);
      return;
    }
  
    HTTPClient http;
    http.begin(msg_url);
    http.addHeader("Content-Type","application/json");
    http.addHeader("Authorization","Bearer " + token);
    String json = "{\"messages\":[{\"type\":\"text\",\"text\":\"" + message + "\"}]}";
    http.POST(json);
    http.end();

    led_red(OFF);
}

void blink_red(int no) {
  int onoff = 1;
  int i;
  for (i=0; i<no*2 ;i++) {
    delay(100);
    if (onoff==0) led_red(ON);
    else          led_red(OFF);
    onoff ^= 1;
  }
}

int read_setup_file(char* fileName) {
  char  buff[128];

  if (!SD.begin(SD_CS, SPI, 24000000)) return 1;

  File setupFile = SD.open(fileName,FILE_READ);
  if (setupFile) {
    readLine(setupFile,buff);
    decrypt(ssid,buff,crypt_key);
    
    readLine(setupFile,buff);
    decrypt(password,buff,crypt_key);
    
    readLine(setupFile,buff);
    decrypt(channel_id,buff,crypt_key);
    
    readLine(setupFile,buff);
    decrypt(channel_pw,buff,crypt_key);

    readLine(setupFile,message1);
    readLine(setupFile,message2);
    setupFile.close();
  }

  return 0;
}

// microSDから１行読み取る
int readLine(File fp, char *buff){
  int i = 0;
  if(!fp.available()) {
    return -1;
  }
  while (fp.available()) {
    char c = fp.read();
    if (c=='\r');
    else if (c=='\n') break;
    else buff[i++] = c;
  }
  buff[i] = 0;
  
  return i;
}

void decrypt( char*a, char*b, char* key) {
  char x[128];
  int i,j,k,m;
  // ascii文字をbinaryに戻す
  for(i=0; b[i]!=0; i++) {
    x[i] = b[i] - (int)'#';
  }
  m = i - 1;

  // 6bit -> 8bit
  j = 0;
  for(i=0; j<m ; i++) {
    switch (i%3) {
      case 0:
        a[i] = (x[j]&0x3F)<<2 | (x[j+1]&0x30)>>4;
        j++;
        break;
      case 1:
        a[i] = (x[j]&0x0F)<<4 | (x[j+1]&0x3C)>>2; 
        j++;
        break;
      case 2:
        a[i] = (x[j]&0x03)<<6 | x[j+1]&0x3F;
        j += 2;
        break;
    }
  }
  m = i;
  
  k = 0;
  int n = strlen(key);
  for (i=0; i<m; i++) {
    a[i] ^= key[k++];
    k %= n;
  }
  a[i]= 0;
}
//---------------------------------------------------------------
// EOF
//---------------------------------------------------------------

MicroSDにはテキストファイル(setup.txt)を格納してあり、中に暗号化したWiFiのアクセスポイント名(SSID)、パスワード(SSID-PW)、LINE Channel ID、Channel IDパスワード、及び平文の起動時のメッセージ、印刷終了時のメッセージを記載してあります。文字コードはUTF-8です（Arduino-IDEがUTF-8なので）。Windows10のメモ帳はデフォルトでUTF-8のようです。

暗号化前のテキストファイルは以下のような感じ。

後述のプログラムで暗号化すると以下のようになります。ファイル名は元のファイル名に_crypt.txt が付いたものになるので、これをsetup.txtという名前に変更してmicroSDのトップ階層に置きます。

microSDに保存するテキストの暗号化プログラムはWindowsのターミナルから以下のように使います。入力ファイルの始めの4行のみ暗号化し、そのあとは平文のまま出力します。"Open Sesame"は任意の文字列で暗号化のキーになります。スケッチ内にも同じものを記載します。

encrypt.exe "Open Sesame" setup_Plain.txt

encrypt.exeプログラムをzip圧縮して、certutilでテキストにエンコードしたものが以下です。ウィルススキャン済み。ターミナルから以下のコマンドでzipに戻せます。

certutil -f -decode [Input Filename] [Output Filename]

2025年2月24日月曜日

WiFiルータの壁掛け治具を3Dプリンタで作る

工作部屋までの天井裏へのLANケーブル敷設はまだだけど、部屋に置くメッシュWiFi中継器の置き場所を検討した。LANケーブルは天井から来るので、天井近くに配置したほうが配線が楽だし、電波の通りもよさそう。そこで、WiFiルータAX1800HP（製品名はWXなのかAXなのかよくわからないがセット品がWXなのか）を壁に取り付ける壁掛け治具を作ることにした。

壁掛け治具はNECの純正品が売られているが、当初ネットで見たら4,400円もしていて、こんな樹脂製のオプション品が流石に高すぎ！と思い、3Dプリンタで自作することにした次第。でもさっき見たら2,200円オフクーポンがあって半額で買える。それでも(私には)高いけど。下の写真が自作した壁掛け治具とルータ。